Hỏi về Lập trình kết hợp giữa Excelvới VBA

  • Thread starter thonon
  • Ngày gửi
P

ptdzung

Guest
26/3/05
56
0
0
Hà Nội
To: Anh Lê Văn Duyệt. Tôi đã vào trang web của anh nhưng không tìm thấy bản dịch "Cuốn Excel VBA programing for Dummies", chỉ có mục lục. Làm thế nào để xem được bản dịch của Anh nhỉ?
Xin cám ơn
 
Khóa học Quản trị dòng tiền
levanduyet

levanduyet

Welcome
16/10/04
537
19
18
HCM
my.opera.com
ptdzung nói:
To: Anh Lê Văn Duyệt. Tôi đã vào trang web của anh nhưng không tìm thấy bản dịch "Cuốn Excel VBA programing for Dummies", chỉ có mục lục. Làm thế nào để xem được bản dịch của Anh nhỉ?
Xin cám ơn

Chúng tôi đang chia nhỏ ra dịch. Nên làm sao mà bạn tìm được!
Chắc còn phải lâu.
Thân,
Lê Văn Duyệt
 
W

workman

Guest
22/7/05
372
2
0
51
Ho Chi Minh
Cám ơn bác Duyệt nhiều. Tôi mới coi qua, tối về ngâm cứu kỹ hơn, nhưng thấy rất hay và chi tiết, chắc chắn giúp được nhiều trong công việc hàng ngày của tôi.

Tôi chủ yếu link-up vào trong SQL để xử lý dữ liệu hoặc chạy thẳng query trên SQL. Nếu có công cụ tốt thì có thể làm phân tích trong excel và Access luôn.
 
levanduyet

levanduyet

Welcome
16/10/04
537
19
18
HCM
my.opera.com
workman nói:
Tôi chủ yếu link-up vào trong SQL để xử lý dữ liệu hoặc chạy thẳng query trên SQL. Nếu có công cụ tốt thì có thể làm phân tích trong excel và Access luôn.
Chào workman,
Ủa Admin cho phép bạn vào trực tiếp nguồn dữ liệu à?
Rất nguy hiểm nếu làm theo cách đó.

Lê Văn Duyệt
 
T

tienhoang

Guest
21/6/05
4
0
0
43
Hanoi
Anh Duyệt ơi! Em Hoàng ở ngoài Hn đây. Anh còn nhớ em chứ. Hôm nay em mới có thời gian dạo qua Excel Club thấy hay quá. Em đang muốn nghiên cứu về VBA nhưng tìm mãi chẳng thấy chỗ down cuốn Excel VBA programing for Dummies trên trang web của anh. Anh chỉ cho em với.
 
D

daovietcuong

Guest
Dear all,
----------
Thực ra hoàn toàn có thể lập trình trên MS Access để điều khiển Excel!
Muốn thực hiện được cần phải bổ sung thư viện:
- Trong dự án mdb, referent đến đối Excel
- Khai báo một đối tượng kiểu excel.workbook và làm việc với nó (các work book này cũng có đầy đủ tập hợp và thuộc tính như một workbook thực sự
---------------------------------
Always careful - Always successful
 
W

workman

Guest
22/7/05
372
2
0
51
Ho Chi Minh
daovietcuong nói:
Dear all,
----------
Thực ra hoàn toàn có thể lập trình trên MS Access để điều khiển Excel!
Muốn thực hiện được cần phải bổ sung thư viện:
- Trong dự án mdb, referent đến đối Excel
- Khai báo một đối tượng kiểu excel.workbook và làm việc với nó (các work book này cũng có đầy đủ tập hợp và thuộc tính như một workbook thực sự
---------------------------------
Always careful - Always successful
Hà hà, có thêm một cao thủ nữa rồi. Tôi cũng thường xuyên dùng Access để xử lý Excel (tiện tay thôi, khỏi phải chạy đi chạy lại giữa hai chương trình). Bắt tay cái nào!!!
 
Đào Việt Cường

Đào Việt Cường

Moderator
22/11/05
400
4
18
Khánh Hòa
workman nói:
Hà hà, có thêm một cao thủ nữa rồi. Tôi cũng thường xuyên dùng Access để xử lý Excel (tiện tay thôi, khỏi phải chạy đi chạy lại giữa hai chương trình). Bắt tay cái nào!!!

Dear workman,
Đến nay workman đã hoàn chỉnh được project nào chưa? Mình là dân kế toán, nhưng luôn mày mò, tìm kiếm công cụ quản lý. Mình cũng có mấy đứa bạn say mê và muốn thành lập nhóm kế toán. Thời gian chủ yếu là làm việc ở văn phòng, tối mới tranh thủ gặp nhau được. Nên mọi thứ hiện giờ vẫn chỉ là ý tưởng, muốn có chuyên gia để động viên cổ vũ! Ban đầu lập Access club thấy hào hứng lắm, nhưng giờ thấy chầm quá... lâu dần thấy chán!
Bọn mình hi vọng tham gia diễn đàn sẽ có thêm luồng sinh khí, tự tin để tiếp tục nghiên cứu. Hãy động viên cổ vũ bọn mình nhé!
:two: :two: :two:
 
T

Tuanktcdcn

Lão già ham vui
18/6/04
549
52
28
47
Hà Nội
www.bluesofts.net
Tất cả các Application thuộc bộ Office đều dùng VBA. Với cái chung như vậy thì làm trên cái nào cũng được. Trong VBE chỉ cần chọn menu Tools\References và nhúng các thành phần là được.
Sau khi làm như trên thì gần như tất cả các Sub và Function trong EXCEL có thể dùng cho Access.
Lý do dùng chung được là do VBE dùng chung VBE/VBA6 .dll, MSO*.dll.
 
W

workman

Guest
22/7/05
372
2
0
51
Ho Chi Minh
Đào Việt Cường nói:
Dear workman,
Đến nay workman đã hoàn chỉnh được project nào chưa? Mình là dân kế toán, nhưng luôn mày mò, tìm kiếm công cụ quản lý. Mình cũng có mấy đứa bạn say mê và muốn thành lập nhóm kế toán. Thời gian chủ yếu là làm việc ở văn phòng, tối mới tranh thủ gặp nhau được. Nên mọi thứ hiện giờ vẫn chỉ là ý tưởng, muốn có chuyên gia để động viên cổ vũ! Ban đầu lập Access club thấy hào hứng lắm, nhưng giờ thấy chầm quá... lâu dần thấy chán!
Bọn mình hi vọng tham gia diễn đàn sẽ có thêm luồng sinh khí, tự tin để tiếp tục nghiên cứu. Hãy động viên cổ vũ bọn mình nhé!
:two: :two: :two:
Có mấy cái lặt vặt thôi. Hồi đầu chủ yếu viết dựa vào công cụ có sẵn. Lệnh chủ yếu thông qua macros (macro của access mạnh ra phết, hơn hẳn excel), phần lập trình chủ yếu để xử lý mấy thứ phức tạp. Làm mấy cái form nhập liệu, lọc dữ liệu và xử lý đơn giản.

Sau này lại đâm ra lười, mấy cái công cụ sau này chủ yếu lại đi sâu vào query, pass-through query (link vào sql) và lập trình xử lý dữ liệu.
 
W

workman

Guest
22/7/05
372
2
0
51
Ho Chi Minh
Tuanktcdcn nói:
Tất cả các Application thuộc bộ Office đều dùng VBA. Với cái chung như vậy thì làm trên cái nào cũng được. Trong VBE chỉ cần chọn menu Tools\References và nhúng các thành phần là được.
Sau khi làm như trên thì gần như tất cả các Sub và Function trong EXCEL có thể dùng cho Access.
Lý do dùng chung được là do VBE dùng chung VBE/VBA6 .dll, MSO*.dll.
Tuân mến,

Đấy là đứng trên quan điểm dân lập trình chuyên nghiệp như Tuân. Chứ như dân kế toán nghiệp dư như bọn mình, Access khác rất nhiều so với excel đấy. Bọn mình dùng Access để làm những mẫu biểu nhanh hơn và nhìn "có vẻ" chuyên nghiệp hơn.

Gặp những database lớn (trên 100,000 record) thì access là lựa chọn tương đối tốt, nhất là xử lý bằng query.

Còn phần lập trình thì bạn nói đúng hoàn toàn, dùng môi trường nào thì cũng như nhau thôi.
 
T

Tuanktcdcn

Lão già ham vui
18/6/04
549
52
28
47
Hà Nội
www.bluesofts.net
paulsteigel

paulsteigel

Trung cấp
13/11/05
103
0
16
48
Hoà Bình
www.sfdp.net
Tặng các bạn phần nhỏ này nhé... Mình muốn VBulletin có thể đinh dạng đẹp như Word nhưng nỏ được...
đành phải dùng biện pháp này vậy.
Lập trình với đối tượng VBA
Mục lục
Mục lục 1
Để bắt đầu, các bạn cần phải tham chiếu đến bộ thư viện mở rộng của VBA 2
Các đối tượng VBE 2
Khai báo tham chiếu đối tượng 3
Thêm một Module vào một bảng tính 4
Xoá module khỏi bảng tính 4
Thêm thủ tục vào một Module 4
Creating An Event Procedure 5
Xoá một thủ tục trong một Module 5
Xoá toàn bộ mã chương trình trong một Module 6
Liệt kê tất cả các Module trong một bảng tính (WorkBook) hoặc tài liệu (Document) 6
Liệt kê tất cả các thủ tục trong một Module 7
Truy xuất tất cả các Modules trong dự án VBA 7
Xoá toàn bộ mã VBA trong một dự án VBA 8
Sao chép Module giữa các dự án VBA 8
Kiểm tra sự tồn tại của một thủ tục hoặc Module 9

Bộ soạn thảo VBE là một công cụ dùng để tạo lập, sửa đổi và khai thác các thủ tục và mô đun trong các ứng dụng Office. Thông qua môi trường soạn thảo, chúng ta có thể tạo ra các ứng dụng VBA bao gồm nhiều đối tượng ví dụ Form, báo cáo, module, bảng tính, tài liệu ... trong tất cả các ứng dụng sẵn có hiện nay của bộ Office như Access, Word, Excel. giống như chúng ta vẫn thao tác thông qua giao diện sử dụng của các ứng dụng đó. Không những thế VBA còn cho phép chúng ta sửa đổi các đối tượng và các module mã giống như chúng ta dùng giao diện của bộ soạn thảo VBE IDE. Tuy nhiên những khả năng này chỉ có từ các phiên bản Office 97 trở lên.
Có khá nhiều câu hỏi liên quan đến vấn đề làm thế nào để có thể phát sinh ra các mã chương trình từ chính các ứng dụng giống như ta dùng công cụ ghi Macro. Để đáp ứng vấn đề này, tôi xin phép được trích dẫn một số tài liệu và đưa ra một cách đơn giản để những ai có mong muốn có thể thực hiện được.
Trong phạm vi bài viết này, chúng ta cùng bàn về một số đối tượng, cách thức và các thuộc tính mà qua đó VBE cho phép chúng ta quản lý môi trường VBA. Microsoft quả là rất cẩn thận khi họ chú trọng đưa những hỗ trợ về vấn đề này vào ngay trong bộ trợ giúp. Với tất cả các phiên bản Office từ 2000 trở lên, các bạn có thể tìm được những hỗ trợ cần thiết chỉ bằng phím F1. Đối với phiên bản 97, để có được những trợ giúp này, chúng ta cần phải tìm trong bộ hỗ trợ nằm trong một đĩa CD khác không thuộc bộ cài đặt Office.
Để bắt đầu, các bạn cần phải tham chiếu đến bộ thư viện mở rộng của VBA
Trong màn hình soạn thảo VBA, chọn Tools, chọn mục Reference và chọn thư viện "Microsoft Visual Basic For Applications Extensibility" qua hộp kiểm bên cạnh. Công việc này sẽ cho phép VBA tìm ra những định nghĩa cần thiết của các đối tượng thuộc VBA như Module, Component...
Nếu các bạn đang dùng các phiên bản Office 2000 hay 2002, tên bộ thư viện sẽ kèm theo số phiên bản. Ví dụ "Microsoft Visual Basic For Applications Extensibility 5.3". Điều này rất quan trọng bởi nếu bạn chỉ ra không đúng bộ thư viện, các bước sau của bạn sẽ gặp rất nhiều lỗi, một trong những lỗi cơ bản là "Type Mismatch" (Không hợp kiểu). Nếu bạn không trỏ tham chiếu, bạn sẽ nhận được thông bào "User Defined Type Not Defined"( Kiểu người dùng định nghĩa chưa được định nghĩa).
Do những cải thiện về an ninh trong các phiên bản Office, để có thể bắt đầu khai thác tính năng này, hãy điều chỉnh cấp an ninh trong thực đơn Tools>Macros>Security thuộc Tab Trust "Trusted Sources" về mức "Trust access to Visual Basic Project".
Lưu ý: Trong tất cả các phiên bản Office đặc biệt là trong Excel, không được khoá các dự án VBProject. Nếu bạn khoá các dự án này thì các công đoạn sẽ bàn đến sau đây đều không thể thực hiện được và bạn sẽ nhận được báo lỗi.
Ngoài ra, bạn cũng sẽ nhận được những thông báo lỗi hoặc những kết quả không mong đợi nếu cố gắng sửa chữa mã chương trình trong chính Module chúng ta đang làm việc. Ví dụ ta đang thực thi chương trình trong Module 1 thì tránh không chỉ thị cho chươn trình thực hiện thay đổi với Module 1 này.
Thêm một vấn đề khác: Nhiều loại mã độc hại hoặc virus cũng lây lan trên cơ chế mà chúng ta sắp bàn này. Vì vậy hầu hết các chương trình quét Virus đều dựa vào đặc điểm này để xoá đi các đoạn mã dùng để sản sinh mã VBA, một số khác thì có thể xoá tất cả. Vì vậy cần phải tắt các chức năng cảnh báo hoặc quét virus của chương trình quét virus trước khi bước vào thực hiện các bước sẽ miêu tả dưới đây.
Các đối tượng VBE
Về cơ bản, chúng ta chỉ cần đến 3 đối tượng dưới đây trong các module của mình:
VBProject: Đây là toàn bộ các module VBA và tham chiếu liên quan đến một bảng tính hoặc một cơ sở dữ liệu hoặc một tài liệu Word cũng như một Slide trong Powerpoint ....
VBComponent: Đây là các thành phần thuộc một dự án VBProject. Ví dụ đó có thể là một Form, một module mã chương trình. Và bộ các thành phần VBComponents sẽ là nơi chứa các thành phần đơn lẻ VBComponent trong dự án của chúng ta.
CodeModule: Đây là đối tượng chỉ ra các đoạn mã thực tế nằm trong một thành phần. Ví dụ khi bạn vào viết mã vào Module 1, điều đó có nghĩa là bạn đang viết mã vào đối tượng CodeModule của thành phần VBComponent có tên là "Module1".
Sau đây chúng ta sẽ đi qua các đối tượng này xét trên ví dụ về đối tượng bảng tính của Excel. Tất nhiên, bạn cũng có thể tiếp cận các đối tượng này thông qua việc gọi trực tiếp VBE từ cấp ứng dụng dưới dạng Application.VBE.
VBA xây dựng bộ định dạng kiểu cho các thành phần này, chúng ta có thể thấy rõ trong phần mô tả dưới đây.
Kiểu Miêu tả
vbext_ct_ClassModule Đây là module lớp được dùng để tạo các đối tượng cho riêng bạn.
vbext_ct_Document
Đây là thành phần giúp chúng ta tạo các bảng tính, tài liệu, biểu đồ...
vbext_ct_MSForm Đây là thành phần giúp ta tạo các đối tượng form
vbext_ct_StdModule
Kiểu định dạng này giúp chúng ta tạo các module mã và các thủ tục cho nó.
Khai báo tham chiếu đối tượng
Chắc hẳn chúng ta cũng đã quen thuộc với các từ khoá khai báo Dim, Public, Private trong môi trường lập trình. Để có thể sử dụng các thành phần và đối tượng, chúng ta cần khai báo để khởi tạo tham chiếu đến chúng trước. Dưới đây là một số cách khai báo và tham chiếu đối tượng
Để có một cách hiểu khái quát, VBA tham chiếu đến các thành phần của chúng thông qua các từ khoá đặc tả, ví dụ với Word đó là ThisDocument, Excel là ThisWorkbook.... Để tham chiếu trực tiếp đến các đối tượng thuộc nó, ta chỉ cần đưa ra từ khoá trên và gõ thêm VBProject
VBProject
Khai báo tham chiếu như thế này
Dim VBProj As VBProject
Dim VBComp As VBComponent
Dim VBCodeMod As CodeModule
Khởi tạo biến đối tượng thế này (Vì đây là biến đối tượng nên muốn gán giá trị ta phải dùng từ khoá Set). Nếu muốn gán trực tiếp cho một đối tượng hiện hữu ta có thể viết lệnh như trong phần được đánh dấu [*]
Set VBProj = ThisWorkbook.VBProject
Set VBComp = ThisWorkbook.VBProject.VBComponents("Module1")*
Set VBCodeMod = ThisWorkbook.VBProject.VBComponents("Module1").CodeModule
Để các bạn tiện theo dõi, chúng ta xét đến ví dụ với đối tượng làm việc là ThisWorkbook, tất nhiên bạn cũng có thể làm việc với ThisDocument hoặc bất kỳ một đối tượng nào khác bằng các mở đối tượng đó ra hoặc tham chiếu trực tiếp đến Active[Workbook hoặc Document] hoặc cũng có thể tham chiếu bằng từ khoá WorkBooks([“Tên WorkBook”] hoặc [Tên tài liệu Word, PowerPoint]).

Thêm một Module vào một bảng tính
Thủ tục dưới đây sẽ giúp bạn thêm một module mới vào ThisWorkBook. Thủ tục đó có tên là "TestModule".
Sub AddModule()
Dim VBComp As VBComponent
Set VBComp = ThisWorkbook.VBProject.VBComponents.Add(vbext_ct_StdModule)
VBComp.Name = "TestModule"
Application.Visible = True
End Sub
Tất nhiên khi bạn thực thi đoạn code này trong Excel lúc màn hình soạn thảo VBE đang mở, bạn sẽ được chuyển tới màn hình chứa Module mới này và mã thực thi kết thúc. Khi bạn thực thi gián tiếp không mở màn hình VBE, Excel sẽ vẫn kích hoạt song không nhận được trỏ kích hoạt (Focus Pointer), sau khi thực hiện xong, Excel sẽ lại có trỏ kích hoạt.
Xoá module khỏi bảng tính
Tương tự chúng ta cũng có thể tiến hành xoá module khỏi bảng tính
Sub DeleteModule()
Dim VBComp As VBComponent
Set VBComp = ThisWorkbook.VBProject.VBComponents("TestModule")
ThisWorkbook.VBProject.VBComponents.Remove VBComp
End Sub
Bạn không thể xoá được Module mã chương trình của đối tượng ThisWorkBook hoặc ThisDocument hoặc các đoạn code module của đối tượng như WorkSheet, Chart ....
Thêm thủ tục vào một Module
Đoạn mã sau sẽ thêm một thủ tục TestProc vào Module TestModule sau khi nó được tạo ra.
Sub AddProcedure()
Dim VBCodeMod As CodeModule
Dim LineNum As Long
Set VBCodeMod = ThisWorkbook.VBProject.VBComponents("TestModule").CodeModule
With VBCodeMod
LineNum = .CountOfLines + 1
.InsertLines LineNum, _
"Sub TestProc()" & Chr(13) & _
" Msgbox ""Hi, this is my first test!"" " & Chr(13) & _
"End Sub"
End With
Application.Run "TestProc"
End Sub
Cần chú ý đến cách gọi thủ tục .InsertLines. Toàn bộ thủ tục được gửi vào 1 dòng lệnh, hàm Chr(13) hoặc hằng vbCrlf sẽ là dấu ngắt xuống dòng cho thủ tục. Bạn cũng có thể kèm thêm các hằng ví dụ như vbTab chẳng hạn để định dạng thủ tục cho đẹp
Câu lệnh Application.Run "TestProc" sẽ thực thi thủ tục sau khi bạn khởi tạo xong.
Bạn phải dùng cấu trúc Application.Run để thực thi thay vì gọi tên thủ tục, vì điều này sẽ gây phát sinh lỗi khi gọi đến một thủ tục chưa tồn tại. Thủ tục này sẽ thực thi thành công nếu bạn thêm mã chương trình vào một module khác không nằm trong module hiện thời.
Nếu bạn thêm code vào cùng module thì phải dùng thủ tục Application.OnTime, điều này giúp trả về trỏ kích hoạt cho Excel và Excel sẽ dịch lại đoạn mã và thực thi.
Tuy nhiên, cũng cần chú ý là việc sử dụng Application.OnTime có thể dẫn đến một số trục trặc liên quan đến việc dịch và thực thi. Bạn cần tránh gọi thủ tục mà bạn vừa thêm vào cùng Module khi các thủ tục VBA chưa hoàn toàn kết thúc.
Trong trường hợp này, hãy dùng Application.OnTime Now,"TestProc"
Creating An Event Procedure
Đối tượng CodeModule có một thủ tục gọi là CreateEventProc, thủ tục này cho phép bạn tạo ra một thủ tục sự kiện trong một module lớp, module của Sheet hoặc của ThisWorkbook hay ThisDocument. Điểm hay của thủ tục này là cho phép tự động thêm các khai báo hoàn chỉnh của một thủ tục bao gồm cả tham số ta muốn bổ sung, trong khi đó InsertLines không thể làm được điều đó. Thủ tục này sẽ trả về số thứ tự dòng bắt đầu thủ tục. Do đó sau khi tạo thủ tục bạn có thể dùng InsertLines để thêm thân thủ tục. Dưới đây là một ví dụ trong đó Excel sẽ tạo ra thủ tục sự kiện Workbook_Open trong đó phần thân là mệnh đề Msgbox.
Sub AddEventProc()
Dim StartLine As Long
With ActiveWorkbook.VBProject.VBComponents("ThisWorkbook").CodeModule
StartLine = .CreateEventProc("Open", "Workbook") + 1
.InsertLines StartLine, _
"Msgbox ""Hey guys! You made it!!!"",vbOkOnly"
End With
End Sub
Xoá một thủ tục trong một Module
The procedure below will delete the procedure called "MyTestProc" from the module named "TestModule" in ThisWorkbook.
Sub DelProcedure()
Dim VBCodeMod As CodeModule
Dim StartLine As Long
Dim HowManyLines As Long
Set VBCodeMod = ThisWorkbook.VBProject.VBComponents("TestModule").CodeModule
With VBCodeMod
StartLine = .ProcStartLine("MyTestProc", vbext_pk_Proc)
HowManyLines = .ProcCountLines("MyTestProc", vbext_pk_Proc)
.DeleteLines StartLine, HowManyLines
End With
End Sub

Xoá toàn bộ mã chương trình trong một Module
Thủ tục dưới đây sẽ xoá toàn bộ mã chương trình trong module tên là "TestModule".
Sub DelAllCodeInModule()
Dim VBCodeMod As CodeModule
Dim StartLine As Long
Dim HowManyLines As Long
Set VBCodeMod = ThisWorkbook.VBProject.VBComponents("TestModule").CodeModule
With VBCodeMod
StartLine = 1
HowManyLines = .CountOfLines
.DeleteLines StartLine, HowManyLines
End With
End Sub
Liệt kê tất cả các Module trong một bảng tính (WorkBook) hoặc tài liệu (Document)
Thủ tục sau đây sẽ liệt kê toàn bộ các thủ tục trong Module ThisWorkbook. Có một hàm con được dùng để đưa về kiểu của thủ tục.
Sub ListModules()
Dim VBComp As VBComponent
Dim Msg As String
For Each VBComp In ThisWorkbook.VBProject.VBComponents
Msg = Msg & VBComp.Name & " Type: " & ObjType(VBComp) & vbCrlf
Next VBComp
MsgBox Msg
End Sub

Function ObjType(VBComp As VBComponent) As String
Select Case VBComp.Type
Case vbext_ct_ActiveXDesigner
ObjType = "ActiveX Designer"
Case vbext_ct_ClassModule
ObjType = "Class Module"
Case vbext_ct_Document
ObjType = "Document"
Case vbext_ct_MSForm
ObjType = "MS Form"
Case vbext_ct_StdModule
ObjType = "Standard Module"
Case Else
End Select
End Function

Liệt kê tất cả các thủ tục trong một Module
Sau đây là một ví dụ trong đó tất cả các thủ tục trong Module "MyModule" thuộc ThisWorkbook sẽ được liệt kê ra.
Sub ListProcs()
Dim VBCodeMod As CodeModule
Dim StartLine As Long
Dim Msg As String
Dim ProcName As String
Set VBCodeMod = ThisWorkbook.VBProject.VBComponents("MyModule").CodeModule
With VBCodeMod
StartLine = .CountOfDeclarationLines + 1
Do Until StartLine >= .CountOfLines
Msg = Msg & .ProcOfLine(StartLine, vbext_pk_Proc) & vbCrlf
StartLine = StartLine + .ProcCountLines(.ProcOfLine(StartLine, _
vbext_pk_Proc), vbext_pk_Proc)
Loop
End With
MsgBox Msg
End Sub
Truy xuất tất cả các Modules trong dự án VBA
Ví dụ dưới đây sẽ truy xuất tất cả cá module trong một dự án và lưu thành các tập tin dạng VB. Trong chừng mực nào đó, bạn có thể sử dụng cá mã naỳ để lưu lại công việc của mìnhđể khi cần thiết có thể sử dụng lại.
Sub ExportModules()
Dim VBComp As VBIDE.VBComponent
Dim ObjType As String
For Each VBComp In ActiveWorkbook.VBProject.VBComponents
Select Case VBComp.Type
Case vbext_ct_ClassModule, vbext_ct_Document
ObjType = ".cls"
Case vbext_ct_MSForm
ObjType = ".frm"
Case vbext_ct_StdModule
ObjType = ".bas"
Case Else
ObjType = ""
End Select
If ObjType <> "" Then
VBComp.Export Filename:=ActiveWorkbook.Path & "\" & _
VBComp.Name & ObjType
End If
Next VBComp
End Sub

Xoá toàn bộ mã VBA trong một dự án VBA
Sub DeleteAllVBA()
Dim VBComp As VBIDE.VBComponent
Dim VBComps As VBIDE.VBComponents
Set VBComps = ActiveWorkbook.VBProject.VBComponents
For Each VBComp In VBComps
Select Case VBComp.Type
Case vbext_ct_StdModule, vbext_ct_MSForm, vbext_ct_ClassModule
VBComps.Remove VBComp
Case Else
With VBComp.CodeModule
.DeleteLines 1, .CountOfLines
End With
End Select
Next VBComp
End Sub
Sao chép Module giữa các dự án VBA
Hiện tại không có chức năng này trong trình soạn thảo VBE nhưng chúng ta có thể tự làm điều đó bằng đoạn ví dụ này.
Cách làm là: truy xuất Module của một dự án và sau đó đưa vào một dự án khác. Thủ tục ví dụ này sẽ chép Module1 từ bảng tính Book2 sang Book1.
Sub CopyModule()
Dim FName As String
With Workbooks("Book2")
FName = .Path & "\bkMdl.txt"
.VBProject.VBComponents("Module1").Export Fname
End With
Workbooks("book1").VBProject.VBComponents.Import Fname
Kill FName
End Sub
Bạn có thể cải biến ví dụ này và sao chép toàn bộ các module của một bảng tính sang bảng tính khác. Tất nhiên là ngoại trừ mã chương trính của đối tượng Sheet và ThisWorkbook thông qua vòng lặp như sau:
For Each VBComp In Workbooks("Book2").VBProject.VBComponents
If VBComp.Type <> vbext_ct_Document Then
VBComp.Export Fname
Workbooks("book1").VBProject.VBComponents.Import Fname
Kill Fname
End If
Next VBComp

Kiểm tra sự tồn tại của một thủ tục hoặc Module
Bạn có thể sử dụng công cụ VBA mở rộng để làm điều này thông qua thủ tục như sau.
Function MdlExists(MdlName As String) As Boolean
On Error Resume Next
MdlExists = Len(ThisWorkbook.VBProject.VBComponents(MdlName).Name) <> 0
End Function

Function ProcExists(ProcName As String, MdlName As String) As Boolean
On Error Resume Next
If MdlExists(MdlName) = True Then
ProcExists = ThisWorkbook.VBProject.VBComponents(MdlName) _
.CodeModule.ProcStartLine(ProcName, vbext_pk_Proc) <> 0
End If
End Function
 

Xem nhiều

Webketoan Zalo OA